Laffer curve example

TheoryGuru applications

Load Economicreasoning package only if it is not already loaded

If[Length@Names["PLTools`*"]<10,
Get["http://economicreasoning.com"]]

Setup

mrs[c_,n_]:=-((Derivative[0,1][u][c,n])/(Derivative[1,0][u][c,n]))

basicassumptions={0<(Subscript[τ, L])<(Subscript[τ, H])<1,(Subscript[w, L])>0,(Subscript[w, H])>0,(Subscript[n, L])>0,(Subscript[n, H])>0,(Subscript[c, L])>0,(Subscript[c, H])>0,
(* the line below says that the production function is increasing and weakly concave *)
((Subscript[c, L])-(Subscript[c, H]))((Subscript[n, L])-(Subscript[n, H]))>0,((Subscript[w, L])-(Subscript[w, H]))((Subscript[n, L])-(Subscript[n, H]))≤0,((Subscript[n, L])-(Subscript[n, H]))(Subscript[w, L])≤(Subscript[c, L])-(Subscript[c, H])≤((Subscript[n, L])-(Subscript[n, H]))(Subscript[w, H]),
(* the two lines below are revealed preference *)
(Subscript[u, L])>(Subscript[u, Lb]),((Subscript[u, Lb])-(Subscript[u, H]))((Subscript[c, Lb])-(Subscript[c, H]))>0,(Subscript[c, L])-(Subscript[c, Lb])==((Subscript[n, L])-(Subscript[n, H]))(1-(Subscript[τ, L]))(Subscript[w, L]),
(Subscript[u, H])>(Subscript[u, Hb]),((Subscript[u, Hb])-(Subscript[u, L]))((Subscript[c, Hb])-(Subscript[c, L]))>0,(Subscript[c, H])-(Subscript[c, Hb])==((Subscript[n, H])-(Subscript[n, L]))(1-(Subscript[τ, H]))(Subscript[w, H]),
(* the line below equates MRS to after-tax wage,
which is not relevant unless additional assumptions about MRS are considered *)
(Subscript[m, L])==(1-(Subscript[τ, L]))(Subscript[w, L]),(Subscript[m, H])==(1-(Subscript[τ, H]))(Subscript[w, H])};

ldemandiselastic=((Subscript[w, L])(Subscript[n, L])-(Subscript[w, H])(Subscript[n, H]))((Subscript[n, L])-(Subscript[n, H]))≥ 0;

bothnormalgoods={((Subscript[m, L])-(Subscript[m, H]))((Subscript[n, L])-(Subscript[n, H]))>0};

samerevenue=(Subscript[τ, L])(Subscript[n, L])(Subscript[w, L])==(Subscript[τ, H])(Subscript[n, H])(Subscript[w, H]);

Analytical Results

The high-tax equilibrium could have more work and utility

TheoryGuru[{basicassumptions[[1;;-3]],samerevenue},(Subscript[n, L])>(Subscript[n, H])]

TheoryGuru[{basicassumptions[[1;;-3]],samerevenue},(Subscript[u, L])>(Subscript[u, H])]

These are one in the same

TheoryOverlap[{basicassumptions[[1;;-3]],samerevenue},(Subscript[u, L])>(Subscript[u, H]),(Subscript[n, L])>(Subscript[n, H])]

Without holding revenue constant, the high-tax equilibrium can have more work,
but then one of the goods (leisure) must be inferior

TheoryGuru[{basicassumptions,(Subscript[n, L])<(Subscript[n, H])},Not@bothnormalgoods]

Look at the frontier of the production possibilities between consumption and leisure.  When leisure is a normal good, the wedge between MRS and w - and therefore the marginal tax rate that would be needed to support the allocation as a competitive equilibrium - must increase with the amount of leisure.  But anywhere leisure is an inferior good, it is possible for the wedge to decrease with the amount of leisure.  In other words, a high-tax-rate equilibrium can have more work than a low-tax-rate one.

If the high-tax equilibrium has the same revenue too, then labor demand must be inelastic

We might expect a high-tax-rate high-work equilibrium also has high tax revenue, but that depends on the elasticity of labor demand.  If it diminishes enough, a high-work equilibrium can have less aggregate (pre-tax) labor income and therefore potentially the same or less labor income tax revenue.

TheoryGuru[{basicassumptions,(Subscript[n, L])<(Subscript[n, H]),samerevenue},
Not@bothnormalgoods&&
Not@ldemandiselastic]

TheoryGuru[{basicassumptions,(Subscript[u, L])<(Subscript[u, H]),samerevenue},
Not@bothnormalgoods&&
Not@ldemandiselastic]