Fiscal policy in a two-period neoclassical growth model

TheoryGuru applications

Load Economicreasoning package only if it is not already loaded

If[Length@Names["PLTools`*"]<10,
Get["http://economicreasoning.com"]]

Setup

mrs[c_,n_]:=-((Derivative[0,1][u][c,n])/(Derivative[1,0][u][c,n]))

eqsepeff={mrs[c1,n1]==f'[n1],mrs[c2,n2]==f'[n2],f[n1]+h[k1]==c1+g1+k2-k1,f[n2]+h[k2]==c2+g2-k2,Derivative[1,0][u][c1,n1]==((Derivative[1,0][u][c2,n2])/(1+ρ))(1+h'[k2])};

eqseptax={mrs[c1,n1]==(1-τ1)f'[n1],mrs[c2,n2]==(1-τ2)f'[n2],f[n1]+h[k1]==c1+g1+k2-k1,f[n2]+h[k2]==c2+g2-k2,g1==τ1 n1 f'[n1],g2==τ2 n2 f'[n2] ,Derivative[1,0][u][c1,n1]==((Derivative[1,0][u][c2,n2])/(1+ρ))(1+h'[k2])}

iqseppositive={Derivative[1,0][mrs][c1,n1]>0,Derivative[1,0][mrs][c2,n2]>0,Derivative[0,1][mrs][c1,n1]>0,Derivative[0,1][mrs][c2,n2]>0,
f[n1]>0,f'[n1]>0,f''[n1]≤0,D[n1 f'[n1],n1]>0,
f[n2]>0,f'[n2]>0,f''[n2]≤0,D[n2 f'[n2],n2]>0,h[k1]>0,h[k2]>0,
h'[k2]>0,h''[k2]<0,n1>0,c1>0,n2>0,c2>0,g1≥0,g2≥0,0≤τ1<1,0≤τ2<1,ρ>-1,
Derivative[1,0][u][c1,n1]>0,Derivative[0,1][u][c1,n1]<0,Derivative[2,0][u][c1,n1]<0,Derivative[0,2][u][c1,n1]<0,Derivative[2,0][u][c1,n1]Derivative[0,2][u][c1,n1]-(((Derivative[1,1][u][c1,n1]))^2)>0,
Derivative[1,0][u][c2,n2]>0,Derivative[0,1][u][c2,n2]<0,Derivative[2,0][u][c2,n2]<0,Derivative[0,2][u][c2,n2]<0,Derivative[2,0][u][c2,n2]Derivative[0,2][u][c2,n2]-(((Derivative[1,1][u][c2,n2]))^2)>0};

A permanent increase in government purchases

Increases the efficient amount of labor

TheoryDifficulty=8; (* optional setting to find solution quicker *)

TheoryGuru[{iqseppositive,Dt[eqsepeff,g],Dt[g1,g]==1,Dt[g2,g]==1,Dt[ρ,g]==0,Dt[k1,g]==0},
Dt[n1,g]>0(* more labor *)]

But not necessarily the equilibrium amount

TheoryGuru[{iqseppositive,Dt[eqseptax,g],Dt[g1,g]==1,Dt[g2,g]==1,Dt[ρ,g]==0,Dt[k1,g]==0},
Dt[n1,g]>0(* more labor *)]

Variable interpretations